android-提示用户选择设备(从行)

我正在尝试列出连接的adb设备,并提示用户选择要部署APK的行.

到目前为止,我已经尝试过：

for %%i in (adb devices) do (
    ECHO %%i
)

但这根本行不通.有什么方法可以将每个adb设备的ID捕获到变量中？我的目标是尽可能地捕获每个ID,例如：

%line1=f2ea3410

从adb列出adb设备：

f2ea3410        device
f2fa3410        device

因此,我可以提示用户该行(而不是提示用户键入的ID)：

@ECHO OFF
set /p id="Enter Line:"

解决方法:

我用您提供的示例对此进行了测试.只需修改：DoIt即可对可用ID进行任何操作.

@setlocal ENABLEEXTENSIONS ENABLEDELAYEDEXPANSION
@rem @set prompt=$G

@set _command=adb.cmd
@set _count=0

@for /f "tokens=1,*" %%G in ('%_command% devices') do @call :AddAndDisplayDevice %%G "%%H"
@set /p _choice=Enter number from above menu:
@if not defined _%_choice% @goto :BadSelection "%_choice%"
@call :DoIt %_choice%
@exit /b 0

:AddAndDisplayDevice
@set /a _count+=1
@echo %_count%. %*
@call :SetVar %_count% %1
@call :SetVar %_count%_description %2
@exit /b 0

:BadSelection
@rem Up to you whether to loop back and try again.
@echo Bad choice: %_choice%
@exit /b -1

:DoIt
@set _Id=!_%1!
@rem set _
@echo User selected %1, device Id %_Id%.
@exit /b 0

:SetVar
@set _%1=%2
@exit /b 0

Adb.cmd,用于测试：

@echo f2ea3410        device
@echo f2fa3410        device

标签：android,windows-10,batch-file,adb
来源： https://codeday.me/bug/20191009/1882512.html