特权级转移 之 保护模式下代码段(一致性代码段 非一致性代码段)特权级保护依据
作者：互联网
学习自唐佐林老师
提炼：
可以 不使用 调用门(低特权级跳转到高特权级) 和 TSS任务状态段(高特权级跳转到低特权级) 的情况下 做代码段之间的跳转(特权级切换)，所使用的就是保护模式下对于代码段特权级保护的依据，即 一致性代码段 与 非一致性代码段的规则。
1 对于非一致性代码段，只能同级转移
其他同特权级代码段(不限一致或非一致) -----跳转到—> 当前非一致性代码段
2 对于一致性代码段，支持低特权级到高特权级一致性代码段的转移，但是！！！ 但是转移之后 CPL不变！！！
正常通过调用门跳转到高特权级，代码段CPL 会被赋值为当前内存段的DPL ，但是 这里 对于一致性代码段，不适用！！！
其他低(同)特权级代码段 -----跳转到—> 当前高特权级一致性代码段
3 特权级降低转移到时候，即执行 retf指令的时候，会触发处理器会对栈段特权级的检查，直接通过选择子中的RPL 进行检查，具体就是 SS的选择子请求特权级RPL 要等于 代码段的选择子请求特权级RPL
4 一致性代码段可以直接跳转到其他同级非一致性代码段执行
一致性代码段与非一致性代码段 中的代码没有本质区别，这两种代码段仅仅是跳转时使用的合法性判断规则不同，因此，一致性代码段到非一致性代码段的直接同级跳转是合法的
系统段与非系统段的区分就是看 段描述符内存结构中 高32位的第12位，注意这里所说的系统段与非系统端 指的并不是操作系统，而是处理器本身，比如系统段 具体一点就是 局部段描述附表，TSS任务状态段等，特点就是 处理器需要他们来完成一些关键的功能，如 LDT与TSS是多任务实现的基础，因此他们是系统段
而非系统段 指的就是通常定义的 代码段与数据段，对于代码段而言，又分为 一致性代码段与非一致性代码段
段描述符内存结构中 Type字段： 高32位的第8 - 11 位，判断是不是一致性代码段就是 C位的值
这里的跳转不借助于 调用门描述符！！！
一致性代码段与非一致性代码段 之间的差异 主要体现在代码段之间进行跳转的时候
如果想要跳转到非一致性代码段，必须满足 一下两个条件：
CPL == DPL 当前代码段可执行特权级 == 目标内存段特权级
RPL <= DPL 目标内存选择子请求特权级要高于目标内存特权级
即平级跳转
如果想要跳转到 一致性代码段，那么就只支持从 低(同)特权级的代码 向 高特权级的一致性代码段转移，也就是说 成功跳转的条件是 CPL >= DPL, 即当前代码段可执行特权级 低于或等于 目标内存段特权级，表面看，这个是很厉害的，在不借助调用门描述符的情况下，直接从低特权级跳转到高特权级，虽然能直接跳转，但是，但是，但是 跳转后CPL特权级不会发生改变。比如，当前想从特权级为1的代码段 跳转到 特权级为0 的一致性代码段 那么在我们跳转过去之后，CPL并不会自动等于 当前内存段特权级0，而是依旧是1，不会发生变化！！！
实验：代码段的直接跳转规则
%include "inc.asm"
org 0x9000
jmp ENTRY_SEGMENT
[section .gdt]
; GDT definition
; 段基址， 段界限， 段属性
GDT_ENTRY : Descriptor 0, 0, 0
CODE32_DESC : Descriptor 0, Code32SegLen - 1, DA_C + DA_32 + DA_DPL1
VIDEO_DESC : Descriptor 0xB8000, 0x07FFF, DA_DRWA + DA_32 + DA_DPL2
DATA32_DESC : Descriptor 0, Data32SegLen - 1, DA_DR + DA_32 + DA_DPL2
STACK32_DESC : Descriptor 0, TopOfStack32, DA_DRW + DA_32 + DA_DPL1
;非一致性代码段 属性 DA_C
FUNCTION_DESC : Descriptor 0, FunctionSegLen - 1, DA_C + DA_32 + DA_DPL1
;一致性代码段 属性DA_CCO 特权级0
NEW_DESC : Descriptor 0, NewSegLen - 1, DA_CCO + DA_32 + DA_DPL0
; GDT end
GdtLen equ $ - GDT_ENTRY
GdtPtr:
dw GdtLen - 1
dd 0
; GDT Selector
Code32Selector equ (0x0001 << 3) + SA_TIG + SA_RPL1
VideoSelector equ (0x0002 << 3) + SA_TIG + SA_RPL2
Data32Selector equ (0x0003 << 3) + SA_TIG + SA_RPL2
Stack32Selector equ (0x0004 << 3) + SA_TIG + SA_RPL1
;非一致性代码段 选择子
FunctionSelector equ (0x0005 << 3) + SA_TIG + SA_RPL1
;一致性代码段选择子
NewSelector equ (0x0006 << 3) + SA_TIG + SA_RPL0
; end of [section .gdt]
TopOfStack16 equ 0x7c00
[section .s16]
[bits 16]
ENTRY_SEGMENT:
mov ax, cs
mov ds, ax
mov es, ax
mov ss, ax
mov sp, TopOfStack16
; initialize GDT for 32 bits code segment
mov esi, CODE32_SEGMENT
mov edi, CODE32_DESC
call InitDescItem
mov esi, DATA32_SEGMENT
mov edi, DATA32_DESC
call InitDescItem
mov esi, STACK32_SEGMENT
mov edi, STACK32_DESC
call InitDescItem
;非一致性代码段 初始化段描述符
mov esi, FUNCTION_SEGMENT
mov edi, FUNCTION_DESC
call InitDescItem
;一致性代码段 初始化段描述符
mov esi, NEW_SEGMENT
mov edi, NEW_DESC
call InitDescItem
; initialize GDT pointer struct
mov eax, 0
mov ax, ds
shl eax, 4
add eax, GDT_ENTRY
mov dword [GdtPtr + 2], eax
; 1. load GDT
lgdt [GdtPtr]
; 2. close interrupt
cli
; 3. open A20
in al, 0x92
or al, 00000010b
out 0x92, al
; 4. enter protect mode
mov eax, cr0
or eax, 0x01
mov cr0, eax
; 5. jump to 32 bits code
push Stack32Selector ; 目标栈段选择子
push TopOfStack32 ; 栈顶指针位置
push Code32Selector ; 目标代码段选择子
push 0 ; 目标代码段偏移
;特权级降低转移到时候，即执行 retf指令的时候，会触发处理器会对栈段特权级的检查，直接通过选择
;子中的RPL 进行检查，具体就是 SS的选择子请求特权级RPL 要等于 代码段的选择子请求特权级RPL
retf
; esi --> code segment label
; edi --> descriptor label
InitDescItem:
push eax
mov eax, 0
mov ax, cs
shl eax, 4
add eax, esi
mov word [edi + 2], ax
shr eax, 16
mov byte [edi + 4], al
mov byte [edi + 7], ah
pop eax
ret
[section .dat]
[bits 32]
DATA32_SEGMENT:
DTOS db "D.T.OS!", 0
DTOS_OFFSET equ DTOS - $$
Data32SegLen equ $ - DATA32_SEGMENT
[section .s32]
[bits 32]
CODE32_SEGMENT:
mov ax, VideoSelector
mov gs, ax
mov ax, Data32Selector
mov ds, ax
mov ax, Stack32Selector
mov ss, ax
mov eax, TopOfStack32
mov esp, eax
;跳转到非一直性代码段
; mov ebp, DTOS_OFFSET
; mov bx, 0x0C
; mov dh, 12
; mov dl, 33
;跳转到 同特权级的 非一致性代码段执行
; call FunctionSelector : PrintString
;跳转到 高特权级的一致性代码段
;从低特权级的非一致性代码段 直接跳转到 高特权级的一致性代码段
;使用jmp 直接从特权级为1的非一致性代码段 跳转到了 特权级为0的代码段 ！！！
;所以 对于一致性的代码段来说，可以直接从低特权级的代码段跳转过来 ！！！
jmp NewSelector : 0
Code32SegLen equ $ - CODE32_SEGMENT
;一致性代码段，必须从低特权级代码(或者同特权级代码段)段跳转过来
[section .new]
[bits 32]
NEW_SEGMENT:
;特点：
;特点1：在特权级为0的一致性代码中 继续跳转(即函数调用)，跳转到 特权级为1的非一致性代码段中去执行
;特点2: 当前代码段是 特权级为0的一致性代码段，而使用的栈段特权级是1
;也就是说直接 降特权级跳转(没有使用retf)，并且使用了不对等的栈段
;所以，虽然可以从低特权级代码(或者同特权级代码段)段跳转过来到 高特权级，还是1，所以说可以直接 跳转
;到 特权级为1的非一致性代码段中去执行，并使用特权级为1的栈段
mov ebp, DTOS_OFFSET
mov bx, 0x0C
mov dh, 12
mov dl, 33
call FunctionSelector : PrintString
jmp $
NewSegLen equ $ - NEW_SEGMENT
;非一致性代码段，只能平级跳转过来
[section .func]
[bits 32]
FUNCTION_SEGMENT:
; ds:ebp --> string address
; bx --> attribute
; dx --> dh : row, dl : col
PrintStringFunc:
push ebp
push eax
push edi
push cx
push dx
print:
mov cl, [ds:ebp]
cmp cl, 0
je end
mov eax, 80
mul dh
add al, dl
shl eax, 1
mov edi, eax
mov ah, bl
mov al, cl
mov [gs:edi], ax
inc ebp
inc dl
jmp print
end:
pop dx
pop cx
pop edi
pop eax
pop ebp
retf
PrintString equ PrintStringFunc - $$
FunctionSegLen equ $ - FUNCTION_SEGMENT
[section .gs]
[bits 32]
STACK32_SEGMENT:
times 1024 * 4 db 0
Stack32SegLen equ $ - STACK32_SEGMENT
TopOfStack32 equ Stack32SegLen - 1
证明 对于一致性代码段，支持低特权级到高特权级一致性代码段的转移，但是！！！ 但是转移之后 CPL不变！！！
反编译：ndisasm -b 32 -o 0x9000 loader > loader.txt
地址
00009115 EA000000003000 jmp dword 0x30:0x0
bochs
6
break 0x9115
info break
c
停到了 指令 ：jmp NewSelector : 0 处
sreg ；查看关键寄存器值
cs:0x0009, 即 1001 最低两位是01 证明当前可执行代码段特权级CPL为1，正是我们定义的特权级
s ;单步执行 单步多次 执行到 指令 call FunctionSelector : PrintString 处
cs:0x0031 最低两位还是 01，证明当前可执行代码段特权级CPL为1，说明此时CPL特权级没有变化！！！
1 特权级降低转移到时候，即执行 retf指令的时候，会触发处理器会对栈段特权级的检查，直接通过选择子中的RPL 进行检查，具体就是 SS的选择子请求特权级RPL 要等于 代码段的选择子请求特权级RPL
2 一致性代码段可以直接跳转到其他同级非一致性代码段执行
一致性代码段与非一致性代码段 中的代码没有本质区别，这两种代码段仅仅是跳转时使用的合法性判断规则不同，因此，一致性代码段到非一致性代码段的直接同级跳转是合法的
CPL DPL RPL 在进行保护模式检查时 所应该遵循的规则
对于数据段，上一节有说明
对于非一致性代码段，只能同级转移
对于一致性代码段，支持低特权级到高特权级一致性代码段的转移，但是！！！ 但是转移之后 CPL不变！！！
正常通过调用门跳转到高特权级，代码段CPL 会被赋值为当前内存段的DPL ，但是 这里 对于一致性代码段，不适用！！！
标签：特权,mov,代码段,DA,跳转,一致性 来源： https://blog.csdn.net/LinuxArmbiggod/article/details/122145873