UVM 寄存器模型的预测(prediction)

文章目录

• UVM 寄存器模型的预测(prediction)
• • prediction的分类
  • 自动预测(auto prediction)
  • 显示预测(explicit prediction)
• 关注作者

mirror、desired和actual value
我们在应用寄存器模型的时候，除了利用它的寄存器信息，也会利用它来跟踪寄存器的值。寄存器模型中的每一个寄存器，都应该有两个值，一个是镜像值(mirrored value)，一个是期望值(desired value)。

• 期望值是先利用寄存器模型修改软件对象值，而后利用该值更新硬件值；镜像值是表示当前硬件的已知状态值。
• 镜像值往往由模型预测给出，即在前门访问时通过观察总线或者在后门访问时通过自动预测等方式来给出镜像值。

镜像值有可能与硬件实际值(actual value)不一致。例如状态寄存器的镜像值就无法与硬件实际值保持同步更新，另外如果其它访问寄存器的通路修改了寄存器，那么可能由于那一路总线没有被监测，因此寄存器的镜像值也无法得到及时更新。

接下来，讨论寄存器模型的预测方式，与上面的三种值相关，这是因为预测行为会直接影响到如何更新镜像值和期望值。在介绍之前需要区别的是，mirrored value与desired value是寄存器模型的属性，而actual value对应着硬件的真实数值。

prediction的分类

• UVM提供了两种用来跟踪寄存器值的方式，我们将其分为自动预测(auto prediction)和显示预测(explicit)。如果用户想要使用自动预测的方法，还需要调用函数uvm_reg_map::set_auto_predict()。
• 两种预测方式的显著差别在于，显示预测对寄存器数值预测更为准确，我们可以通过下面对两种模式的分析得出具体原因。

自动预测(auto prediction)

• 如果用户没有在环境中集成独立的predictor，而是利用寄存器的操作来自动记录每一次寄存器的读写数值，并在后台调用predict()方法的话，这种方式被称之为自动预测。
• 这种方式简单有效，然而需要注意，如果出现了其它一些sequence直接在总线层面上对寄存器进行操作(跳过寄存器级别的write()/read()操作，或者通过其它总线来访问寄存器等这些额外的情况，都无法自动得到寄存器的镜像值和预期值)

显示预测(explicit prediction)

更为可靠的一种方式是在物理总线上通过监视器来捕捉总线事务，并将捕捉到的事务传递给外部例化的predictor，该predictor由UVM参数化类uvm_reg_predictor例化并集成在顶层环境中。

在集成的过程中需要将adapter与map的句柄也一并传递给predictor，同时将monitor采集的事务通过analysis port接入到predictor一侧。

这种集成关系可以使得，monitor一旦捕捉到有效事务，会发送给predictor，再由其利用adapter的桥接方法，实现事务信息转换，并将转换后的寄存器模型有关消息更新到map中。

默认情况下，系统将采用显示预测的方式，这就要求集成到环境中的总线UVC monitor需要具备捕捉事务的功能和对应的analysis port，以便于同predictor连接。

class mcdf_bus_env extends uvm_env;
	mcdf_bus_agent agent;
	mcdf_rgm rgm;
	reg2mcdf_adapter reg2mcdf;
	uvm_reg_predictor #(mcdf_bus_trans) mcdf2reg_predictor;
	`uvm_component_utils(mcdf_bus_env)
	...
	function void build_phase(uvm_phase phase);
		agent=mcdf_bus_agent::type_id::create("agent",this);
		if(!uvm_config_db#(mcdf_rgm)::get(this,"","rgm",rgm))begin
			`uvm_info("GETRGM","no top-down RGM handle is assigned",UVM_LOW)
			rgm=mcdf_rgm::type_id::create("rgm",this);
			`uvm_info("NEWRGM","created rgm instance locally",UVM_LOW)
		end
		rgm.build();
		reg2mcdf=reg2mcdf_adapter::type_id::create("reg2mcdf");
		mcdf2reg_predictor=uvm_reg_predictor#(mcdf_bus_trans)::type_id::create("mcdf2reg_predictor",this);
		mcdf2reg_predictor.map=rgm.map;
		mcdf2reg_predictor.adapter=reg2mcdf;
	endfunction
	function void connect_phase(uvm_phase phase);
		rgm.map.set_sequencer(agent.sequencer,reg2mcdf);
		agent.monitor.ap.connect(mcdf2reg_predictor.bus_in);
	endfunction
endclass

• adapter句柄要给predictor，register map的句柄也要给predictor，predictor拿到trans，要利用adapter里面的bus2reg函数生成regsister_operation,然后利用register map去更新每一个寄存器的数值
• adapter是object,predictor是component
• bus_in是一个默认的analysis import

关注作者

• 自述
  作者是一位中科大数字设计专业的研究生，水平有限，如有错误，请大家指正，想要与大家一同进步。
• 经历
  曾获得国家奖学金，“高教社杯”数学建模国家二等奖等
• 陆续更新：
  1.与UVM验证相关的system verilog后续内容；
  2.与verilog数字设计相关的一些基础模块设计，例如FIFO，UART，I2C等的书写。
  3.保研与竞赛经历等
• 微信公众号
  欢迎大家关注公众号“数字IC小白的日常修炼”,期待与大家一同仗剑遨游数字IC世界。`

标签：27,预测,prediction,predictor,UVM,寄存器,rgm,uvm
来源： https://blog.csdn.net/qq_42419590/article/details/121471186