RationalDMIS 7.1 两圆拟合圆柱（AC-DMIS 5.3,CAMIO,MODUS）

 

要注意的是，如果您使用一个特征的触测点，必须被以相同半径的测头测量。

 

1.对于RationalDMIS 7.1 :

 

 

F(CIR1)=FEAT/CIRCLE,INNER,CART,-0.0000,-0.0000,-10.0000,0.0000,0.0000,1.0000, 30.0000

$$ Measurement points are created through nominal points

MEAS/CIRCLE, F(CIR1), 5

  GOTO/CART,     0.0000,  -0.0000,   6.0000

  GOTO/CART,   -12.0000,   0.0000,   6.0000

  GOTO/CART,   -12.0000,   0.0000,   5.0000

  PTMEAS/CART, -15.0000,   0.0000, -10.0000,  1.0000,  0.0000,  0.0000

  GOTO/CART,   -11.4127,   3.7082, -10.0000

  GOTO/CART,    -9.7082,   7.0534, -10.0000

  GOTO/CART,    -7.0534,   9.7082, -10.0000

  PTMEAS/CART,  -4.6353,  14.2658, -10.0000,  0.3090, -0.9511,  0.0000

  GOTO/CART,     0.0000,  12.0000, -10.0000

  GOTO/CART,     3.7082,  11.4127, -10.0000

  GOTO/CART,     7.0534,   9.7082, -10.0000

  PTMEAS/CART,  12.1353,   8.8168, -10.0000, -0.8090, -0.5878, -0.0000

  GOTO/CART,    11.4127,   3.7082, -10.0000

  GOTO/CART,    12.0000,   0.0000, -10.0000

  GOTO/CART,    11.4127,  -3.7082, -10.0000

  PTMEAS/CART,  12.1353,  -8.8168, -10.0000, -0.8090,  0.5878,  0.0000

  GOTO/CART,     7.0534,  -9.7082, -10.0000

  GOTO/CART,     3.7082, -11.4127, -10.0000

  GOTO/CART,     0.0000, -12.0000, -10.0000

  PTMEAS/CART,  -4.6353, -14.2658, -10.0000,  0.3090,  0.9511,  0.0000

  GOTO/CART,    -3.7082, -11.4127,   5.0000

ENDMES

F(CIR2)=FEAT/CIRCLE,INNER,CART,-0.0000,-0.0000,-2.0000,0.0000,0.0000,1.0000, 30.0000

$$ Measurement points are created through nominal points

MEAS/CIRCLE, F(CIR2), 5

  GOTO/CART,    -3.7082, -11.4127, 14.0000

  GOTO/CART,   -12.0000,   0.0000, 14.0000

  GOTO/CART,   -12.0000,   0.0000, 13.0000

  PTMEAS/CART, -15.0000,   0.0000, -2.0000,  1.0000,  0.0000,  0.0000

  GOTO/CART,   -11.4127,   3.7082, -2.0000

  GOTO/CART,    -9.7082,   7.0534, -2.0000

  GOTO/CART,    -7.0534,   9.7082, -2.0000

  PTMEAS/CART,  -4.6353,  14.2658, -2.0000,  0.3090, -0.9511,  0.0000

  GOTO/CART,     0.0000,  12.0000, -2.0000

  GOTO/CART,     3.7082,  11.4127, -2.0000

  GOTO/CART,     7.0534,   9.7082, -2.0000

  PTMEAS/CART,  12.1353,   8.8168, -2.0000, -0.8090, -0.5878, -0.0000

  GOTO/CART,    11.4127,   3.7082, -2.0000

  GOTO/CART,    12.0000,   0.0000, -2.0000

  GOTO/CART,    11.4127,  -3.7082, -2.0000

  PTMEAS/CART,  12.1353,  -8.8168, -2.0000, -0.8090,  0.5878,  0.0000

  GOTO/CART,     7.0534,  -9.7082, -2.0000

  GOTO/CART,     3.7082, -11.4127, -2.0000

  GOTO/CART,     0.0000, -12.0000, -2.0000

  PTMEAS/CART,  -4.6353, -14.2658, -2.0000,  0.3090,  0.9511,  0.0000

  GOTO/CART,    -3.7082, -11.4127, 13.0000

ENDMES

F(CYL_BF1)=FEAT/CYLNDR,OUTER,CART,0.0000,-0.0000,-6.0000,0.0000,0.0000,1.0000, 30.0000,  8.0000

CONST/CYLNDR,F(CYL_BF1),BF,FA(CIR1)[1],FA(CIR1)[2],FA(CIR1)[3],FA(CIR1)[4],FA(CIR1)[5],FA(CIR2)[1],FA(CIR2)[2],FA(CIR2)[3],FA(CIR2)[4],FA(CIR2)[5]

 

或：

 

F(CYL_BF1)=FEAT/CYLNDR,OUTER,CART,0.0000,-0.0000,-6.0000,0.0000,0.0000,1.0000, 30.0000,  8.0000

CONST/CYLNDR,F(CYL_BF1),BF,FA(CIR1)[1,5],FA(CIR2)[1,5]

 

2.对于AC-DMIS 5.3

 

 

DEFINE CYLINDER 组合圆柱-0

    TOL("X",0.0000,0.0000,-0.0000)

    TOL("Y",0.0000,0.0000,-0.0000)

    TOL("Z",0.0000,0.0000,-0.0000)

    TOL("A1",0.000000,0.0000,-0.0000)

    TOL("A2",0.000000,0.0000,-0.0000)

    TOL("A3",0.000000,0.0000,-0.0000)

    TOL("DIA",0.0000,0.0000,-0.0000)

    TOL("F",0.0000,0.0000,0.0000)

    ADD-COMBINATION("圆-1")

    ADD-COMBINATION("圆-2")

    INOUT-GEOMETRY(-1)

    CALCULATE-TYPE(0)

    IS-MEASURE-PNTS(0)

    CE-CYLINDER("组合圆柱-0",2)

ENDDEF

 

3.对于LK CAMIO（MODUS）来说如下：

 

DECL/GLOBAL,REAL,Pts1

DECL/GLOBAL,REAL,Pts2

$$ Collect points from feature

Pts1=VALUE/FA(CIR001),PTDATA

$$ Collect points from feature

Pts2=VALUE/FA(CIR002),PTDATA

F(CylinderName)=FEAT/CYLNDR,INNER,CART,0,0,0,0,1,0,75.1

CONST/CYLNDR,F(CylinderName),BF,FA(CIR001)[1,Pts1],FA(CIR002)[1,Pts2]

 

 

 

      if a feature has been measured with point buffering enabled, by a PTBUFF/ON statement, then its individual point data can be referenced by appending the [n] option to F(label) or FA(label), where n is the point index from the feature's programmed PTMEAS statements. When the index [n] option for specifying point data is used, the current probe compensation state shall determine whether probe compensation will be applied to the specified data points during the feature construction, as if the constructed feature were measured with that point data with the MEAS or RMEAS statements. If the best fit feature is constructed with point buffering enabled, by a PTBUFF/ON statement, then the individual point data is copied to the point buffer of the constructed feature and is then accessible with the [n] point data index as if it were a feature measured with the MEAS or RMEAS statements. Non-indexed features (specified with FA(label2) without the [n] index option) and indexed feature point data (specified with FA(label2)[n] or FA(label2)[n,m]) cannot be mixed in a single CONST/F(label),BF statement.

 

The CONST ( input format 1 ) statement is passed to the output file when executed.

 

标签：AC,5.3,GOTO,两圆,CART,10.0000,FA,0.0000,2.0000
来源： https://blog.51cto.com/u_14941238/2903556