php – 下载sql表的值以供离线重用

我有一个Flash应用程序调用在线php文件,以读取我的SQL表的一些值.

所以我的AS3代码中有这样一行：

var urlReq:URLRequest = new URLRequest ("http://www.****.com/sql_result.php");

这在我的PHP中：

 $connection = mysql_connect("mysql***.perso", "test", "password") or die ("Couldn't connect to the server.");

问题：如果用户处于离线状态,则无法访问这些值.

有没有办法下载带有AS3代码的SQL表(当用户有互联网时)以便脱机访问它.

喜欢 ：

function onConnection(e:Event = null):void{
if(monitor.available)
            {
                trace("You are connected to the internet");
                read_php_online();
            }
            else
            {
                trace("You are not connected to the internet");
                read_php_offline();
            }

            monitor.stop();
        }

function read_php_offline():void{
    var urlReq:URLRequest = new URLRequest ("local/sql_result_offline.php");
..
..
}

什么应该有sql_result_offline.php才能访问脱机SQL表？

 $connection = mysql_connect("LOCAL", "user", "password");

谢谢,

解决方法:

对于FLASH：

要使用闪存本地保存数据,您可以使用以下三种方式之一：Flash Player缓存,SharedObject或FileReference对象.对于您的本地文件,忘记PHP和MySQL,因为我们只谈论您获得的数据(json,xml,txt,…).

– Flash Player缓存：

您应该知道,默认情况下,Flash播放器会将文件的本地副本放入其缓存中.您可以使用此本地副本作为数据的离线源,但这里不要忘记Flash播放器没有保存远程文件的最新版本,但第一个版本和http://www.example.com/data.php与http://www.example.com/data.php?123不同,即使它是相同的档案！有关详细信息,请查看my answer of this question.

– SharedObject：

我不知道加载数据的大小,但正如Adobe所说的SharedObject：

… is used to read and store limited amounts of data on a user’s computer …

我认为这不是用于大文件,不建议存储文件,而是一些简单的数据.当然,作为浏览器的cookie,SharedOject需要用户授权才能将数据写入硬盘,用户可以随时删除它.

– FileReference：

我认为这是做你想要的最好的方式.您应该知道,要使用FileReference保存文件,系统会邀请您的用户选择一个文件来保存数据并在第二次读取它.因此,如果您不希望任何用户与您的应用程序进行交互,请忘记这种方式.

FileReference使用示例：

var local_file_name:String = 'local.data',
    file:FileReference = new FileReference(),
    local_file_filter:FileFilter = new FileFilter('local data file', '*.data'),
    remote_data_url:String = 'http://www.example.com/data.php',
    url_request:URLRequest,
    url_loader:URLLoader,       
    connected:Boolean = true;

if(connected){
    get_remote_data();
} else {
    get_local_data();
}

function get_remote_data(): void {
    //we use a param to be sure that we have always the last version of our file
    url_request = new URLRequest(remote_data_url + ('?' + new Date().getTime()));
    url_loader = new URLLoader();
    url_loader.addEventListener(Event.COMPLETE, on_data_loaded);
    url_loader.load(url_request);           
}

function get_local_data(): void {
    // show the select dialog to the user to select the local data file
    file.browse([local_file_filter]);
    file.addEventListener(Event.SELECT, on_file_selected);          
}

function on_data_loaded(e:Event): void {
    var data:String = e.target.data;
    // if the remote data is successfully loaded, save it on a local file 
    if(connected){
        // show the save dialog and save data to a local file
        file.save(data, local_file_name);
    }
    // use your loaded data
    trace(data);            
}

function on_file_selected(e:Event): void {
    file.addEventListener(Event.COMPLETE, on_data_loaded);
    file.load();
}

每次向用户提供保存对话框时,此代码都会显示,当然,这只是一个示例,您必须根据自己的需要进行调整…

编辑

对于AIR：

使用AIR,我们不需要FileReference对象,而是使用File和FileStream对象来保存数据：

// for example, our local file will be saved in the same dir of our AIR app
var file:File = new File( File.applicationDirectory.resolvePath('local.data').nativePath ),
    remote_data_url:String = 'http://www.example.com/data.php',
    data_url:String = remote_data_url,
    url_request:URLRequest,
    url_loader:URLLoader,       
    connected:Boolean = true;

if(!connected){
    // if we are not connected, we use the path of the local file
    data_url = file.nativePath;     
}

load_data();

function load_data(): void {
    url_request = new URLRequest(data_url);
    url_loader = new URLLoader();
    url_loader.addEventListener(Event.COMPLETE, on_data_loaded);
    url_loader.load(url_request);           
}

function on_data_loaded(e:Event): void {
    var data:String = e.target.data;
    if(connected){          
        // save data to the local file
        var file_stream:FileStream = new FileStream();
            file_stream.open(file, FileMode.WRITE);
            file_stream.writeUTFBytes(data);
            file_stream.close();
    }
    trace(data);            
}

希望能有所帮助.

标签：php,mysql,local-storage,actionscript-3,air
来源： https://codeday.me/bug/20190928/1825859.html