java-使用gradle为Spring-boot REST服务运行集成测试

我目前正在尝试为基于以下内容的REST服务设置集成测试框架：

>春季靴
>摇篮
>码头

我能够将spring-boot集成测试框架与spring-boot junit运行器一起使用,以调出应用程序上下文并成功运行测试.

我想做的下一件事是执行gradle任务,该任务将执行以下操作：

>建立罐子(不是战争)
>开始码头并部署罐子
>针对此jar运行一组测试用例.
>停止码头

=>我尝试使用“码头”插件.但是它似乎不支持jar文件.
=>然后,我尝试使用JavaExec任务运行jar,然后运行测试,但是在测试完成后,我找不到直接停止jar进程的简单方法.
=> Exec类型任务也存在同样的问题.

因此,我对此有两个问题：

>有没有一种方法可以使用gradle实现上述形式的集成测试.
>是推荐这种集成测试方法还是有更好的方法呢？

非常感谢任何想法和见解.

谢谢,

解决方法:

有多种方法可以实现您想要的.我为客户提供的方法依赖于Spring Boot Actuator提供的/ shutdown URL.重要说明：如果使用此方法,请确保将disable or secure the /shutdown endpoint用于生产.

在构建文件中,您有两个任务：

task startWebApp(type: StartApp) {
    dependsOn 'assemble'
    jarFile = jar.archivePath
    port = 8080
    appContext = "MyApp"
}

task stopWebApp(type: StopApp) {
    urlPath = "${startWebApp.baseUrl}/shutdown"
}

您应该确保集成测试取决于startWebApp任务,并且应该由stop任务完成这些测试.所以像这样：

integTest.dependsOn "startWebApp"
integTest.finalizedBy "stopWebApp"

当然,您也需要创建自定义任务实现：

class StartApp extends DefaultTask {
    static enum Status { UP, DOWN, TIMED_OUT }

    @InputFile
    File jarFile

    @Input
    int port = 8080

    @Input
    String appContext = ""

    String getBaseUrl() {
        return "http://localhost:${port}" + (appContext ? '/' + appContext : '')
    }

    @TaskAction
    def startApp() {
        logger.info "Starting server"
        logger.debug "Application jar file: " + jarFile

        def args = ["java",
                "-Dspring.profiles.active=dev",
                "-jar",
                jarFile.path]
        def pb = new ProcessBuilder(args)
        pb.redirectErrorStream(true)

        final process = pb.start()
        final output = new StringBuffer()
        process.consumeProcessOutputStream(output)

        def status = Status.TIMED_OUT
        for (i in 0..20) {
            Thread.sleep(3000)

            if (hasServerExited(process)) {
                status = Status.DOWN
                break
            }

            try {
                status = checkServerStatus()
                break
            }
            catch (ex) {
                logger.debug "Error accessing app health URL: " + ex.message
            }
        }

        if (status == Status.TIMED_OUT) process.destroy()

        if (status != Status.UP) {
            logger.info "Server output"
            logger.info "-------------"
            logger.info output.toString()
            throw new RuntimeException("Server failed to start up. Status: ${status}")
        }
    }

    protected Status checkServerStatus() {
        URL url = new URL("$baseUrl/health")
        logger.info("Health Check --> ${url}")
        HttpURLConnection connection = url.openConnection()
        connection.readTimeout = 300

        def obj = new JsonSlurper().parse(
            connection.inputStream,
            connection.contentEncoding ?: "UTF-8")
        connection.inputStream.close()
        return obj.status == "UP" ? Status.UP : Status.DOWN
    }

    protected boolean hasServerExited(Process process) {
        try {
            process.exitValue()
            return true
        } catch (IllegalThreadStateException ex) {
            return false
        }
    }
}

请注意,在线程上启动服务器很重要,否则任务永远不会结束.停止服务器的任务更加简单：

class StopApp extends DefaultTask {

    @Input
    String urlPath

    @TaskAction
    def stopApp(){
        def url = new URL(urlPath)
        def connection = url.openConnection()
        connection.requestMethod = "POST"
        connection.doOutput = true
        connection.outputStream.close()
        connection.inputStream.close()
    }
}

它基本上向/ shutdown URL发送一个空的POST来停止正在运行的服务器.

标签：spring-boot,gradle,integration-testing,java
来源： https://codeday.me/bug/20191120/2040703.html